forked from mtusi2026/mtusi2026lab4
133 lines
4.0 KiB
Batchfile
133 lines
4.0 KiB
Batchfile
@echo off
|
|
setlocal EnableDelayedExpansion
|
|
cd /d "%~dp0.."
|
|
|
|
set BASE=http://localhost:8080
|
|
set PASS=Example-only-not-a-real-secret-123
|
|
set FIXTURE=tests\fixtures\sample.png
|
|
set TMP=%TEMP%\lab4-persistence
|
|
if not exist "%TMP%" mkdir "%TMP%"
|
|
|
|
call :guid
|
|
set RND=%GUIDVAL%
|
|
set PUSER=pers%RND%
|
|
|
|
echo === Register persistence user ===
|
|
call :register "%PUSER%" "Persistence" pers
|
|
if errorlevel 1 exit /b 1
|
|
set PUSER_ID=!pers_ID!
|
|
|
|
call :login "%PUSER%" pers
|
|
if errorlevel 1 exit /b 1
|
|
set TOKEN=!pers_TOKEN!
|
|
|
|
echo === Create chat ===
|
|
curl.exe -s -X POST "%BASE%/api/v1/chats" ^
|
|
-H "Authorization: Bearer %TOKEN%" ^
|
|
-H "Content-Type: application/json" ^
|
|
-d "{\"title\":\"Persistence attachment\",\"member_ids\":[\"%PUSER_ID%\"]}" ^
|
|
-o "%TMP%\chat.json" ^
|
|
-w "%%{http_code}" > "%TMP%\chat.code"
|
|
|
|
call :check_code chat.code 201 "create chat"
|
|
if errorlevel 1 exit /b 1
|
|
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\chat.json' -Raw | ConvertFrom-Json).id"') do set CHAT_ID=%%a
|
|
|
|
echo === Upload attachment ===
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-FileHash -Algorithm SHA256 -Path '%FIXTURE%').Hash.ToLower()"') do set ORIG_SHA=%%a
|
|
|
|
curl.exe -s -X POST "%BASE%/api/v1/chats/%CHAT_ID%/attachments?filename=persistence.png" ^
|
|
-H "Authorization: Bearer %TOKEN%" ^
|
|
-H "Content-Type: image/png" ^
|
|
--data-binary "@%FIXTURE%" ^
|
|
-o "%TMP%\att.json" ^
|
|
-w "%%{http_code}" > "%TMP%\att.code"
|
|
|
|
call :check_code att.code 201 "upload attachment"
|
|
if errorlevel 1 exit /b 1
|
|
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\att.json' -Raw | ConvertFrom-Json).id"') do set ATT_ID=%%a
|
|
|
|
echo === Create message with attachment ===
|
|
call :guid
|
|
set KEY=%GUIDVAL%
|
|
|
|
curl.exe -s -X POST "%BASE%/api/v1/chats/%CHAT_ID%/messages" ^
|
|
-H "Authorization: Bearer %TOKEN%" ^
|
|
-H "Idempotency-Key: %KEY%" ^
|
|
-H "Content-Type: application/json" ^
|
|
-d "{\"text\":\"\",\"attachment_ids\":[\"%ATT_ID%\"]}" ^
|
|
-o "%TMP%\msg.json" ^
|
|
-w "%%{http_code}" > "%TMP%\msg.code"
|
|
|
|
call :check_code msg.code 201 "create message"
|
|
if errorlevel 1 exit /b 1
|
|
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\msg.json' -Raw | ConvertFrom-Json).id"') do set MSG_ID=%%a
|
|
|
|
echo === Save state ===
|
|
>"%TMP%\username.txt" echo %PUSER%
|
|
>"%TMP%\token.txt" echo %TOKEN%
|
|
>"%TMP%\chat_id.txt" echo %CHAT_ID%
|
|
>"%TMP%\att_id.txt" echo %ATT_ID%
|
|
>"%TMP%\msg_id.txt" echo %MSG_ID%
|
|
>"%TMP%\sha256.txt" echo %ORIG_SHA%
|
|
|
|
echo State saved to %TMP%
|
|
echo attachment=%ATT_ID%
|
|
echo message=%MSG_ID%
|
|
echo.
|
|
echo Now run:
|
|
echo scripts\restart-stack.bat
|
|
echo scripts\persistence-verify.bat
|
|
exit /b 0
|
|
|
|
:guid
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "[guid]::NewGuid().ToString('N').Substring(0,8)"') do set GUIDVAL=%%a
|
|
exit /b 0
|
|
|
|
:register
|
|
rem %1 username, %2 display_name, %3 prefix
|
|
curl.exe -s -X POST "%BASE%/api/v1/users" ^
|
|
-H "Content-Type: application/json" ^
|
|
-d "{\"username\":\"%~1\",\"display_name\":\"%~2\",\"password\":\"%PASS%\"}" ^
|
|
-o "%TMP%\%~3.json" ^
|
|
-w "%%{http_code}" > "%TMP%\%~3.code"
|
|
|
|
set /p RC=<"%TMP%\%~3.code"
|
|
if not "%RC%"=="201" (
|
|
echo FAIL: register %~1, HTTP %RC%
|
|
type "%TMP%\%~3.json"
|
|
exit /b 1
|
|
)
|
|
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\%~3.json' -Raw | ConvertFrom-Json).id"') do set "%~3_ID=%%a"
|
|
exit /b 0
|
|
|
|
:login
|
|
rem %1 username, %2 prefix
|
|
curl.exe -s -X POST "%BASE%/api/v1/auth/sessions" ^
|
|
-u "%~1:%PASS%" ^
|
|
-o "%TMP%\%~2.json" ^
|
|
-w "%%{http_code}" > "%TMP%\%~2.code"
|
|
|
|
set /p RC=<"%TMP%\%~2.code"
|
|
if not "%RC%"=="201" (
|
|
echo FAIL: login %~1, HTTP %RC%
|
|
type "%TMP%\%~2.json"
|
|
exit /b 1
|
|
)
|
|
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\%~2.json' -Raw | ConvertFrom-Json).token"') do set "%~2_TOKEN=%%a"
|
|
for /f "delims=" %%a in ('powershell -NoProfile -Command "(Get-Content '%TMP%\%~2.json' -Raw | ConvertFrom-Json).user.id"') do set "%~2_UID=%%a"
|
|
exit /b 0
|
|
|
|
:check_code
|
|
rem %1 code file, %2 expected status, %3 label
|
|
set /p RC=<"%TMP%\%~1"
|
|
if not "%RC%"=="%~2" (
|
|
echo FAIL: %~3 expected %~2, got %RC%
|
|
exit /b 1
|
|
)
|
|
exit /b 0 |